Both sensors side by side

// Both sensors side by side: a DHT11 and a DHT22 on one board.
//
// Wiring, both sensors:
//   Sensor GND  -> board GND
//   Sensor VCC  -> board 5V on an Uno, 3V3 on an ESP32, ESP32-S3 or Pico
//   Sensor NC   -> nothing
//   DHT11 DATA  -> Uno D2, ESP32 GPIO 18, ESP32-S3 GPIO 4, Pico GP2
//   DHT22 DATA  -> Uno D3, ESP32 GPIO 19, ESP32-S3 GPIO 5, Pico GP3
//
// Count the pins from the square pad: GND, VCC, NC, DATA. Mount the two
// sensors the same distance from the board -- if one is on the breadboard
// and one is on wires, you are measuring the breadboard.
//
// Arduino IDE: install "DHT sensor library" by Adafruit from the Library
// Manager, and accept "Adafruit Unified Sensor" when it offers it.

#include <DHT.h>

#define PIN_11 2      // Uno D2.  ESP32: 18.  ESP32-S3: 4.  Pico: 2.
#define PIN_22 3      // Uno D3.  ESP32: 19.  ESP32-S3: 5.  Pico: 3.

// One object each, and the type is what makes them different. Nothing on
// the wire tells the library which is which.
DHT blue(PIN_11, DHT11);
DHT white(PIN_22, DHT22);

const unsigned long EVERY = 5000;   // well clear of both sensors' floors
unsigned long last = 0;

void setup() {
  Serial.begin(115200);
  blue.begin();
  white.begin();
  Serial.println("t11,rh11,t22,rh22,dT,dRH");
}

void loop() {
  if (millis() - last < EVERY) return;
  last = millis();

  // Each read blocks: about 24 ms for the DHT11 (20 ms of it just holding
  // the wire down to wake it) and about 6 ms for the DHT22.
  float t11 = blue.readTemperature(),  h11 = blue.readHumidity();
  float t22 = white.readTemperature(), h22 = white.readHumidity();

  if (isnan(t11) || isnan(h11) || isnan(t22) || isnan(h22)) {
    Serial.println("read failed");   // one sensor failing fails the row
    return;
  }

  // Comma separated, so it pastes straight into a spreadsheet.
  Serial.print(t11);  Serial.print(",");
  Serial.print(h11);  Serial.print(",");
  Serial.print(t22);  Serial.print(",");
  Serial.print(h22);  Serial.print(",");
  Serial.print(t11 - t22, 1); Serial.print(",");
  Serial.println(h11 - h22, 1);
}