Dimming with PWM

/*
  Dual Bright LEDs - a fade that looks even              TK95 / /p/tk95

  Wiring. Count from the square pad on the TinkerBlock board, parts
  up, header at the bottom:

    GND    -> GND
    VCC    -> 5V (VBUS on a Pico). It only feeds the LEDs, so 5V is
              safe on a 3.3 V board. Never the Uno's 3.3V pin.
    3000K  -> D9, GPIO 25, GPIO 4 or GP14   (a PWM pin)
    6500K  -> D10, GPIO 26, GPIO 5 or GP15  (a PWM pin)

  Uno, ESP32, ESP32-S3, Pico, in that order.

  Arduino IDE
    Tools > Board                 your board, e.g. ESP32S3 Dev Module
    Tools > Port                  the one that appears when you plug in
    Tools > USB CDC On Boot       Enabled   (ESP32-S3 only)
    No library needed.
    Serial Monitor                115200
*/

// The pins 3000K and 6500K are wired to.
// Uno: 9. ESP32: 25. ESP32-S3: 4. Pico: 14.
const int WARM_PIN = 4;
// Uno: 10. ESP32: 26. ESP32-S3: 5. Pico: 15.
const int COOL_PIN = 5;

// Two thirds of full: the cap for VCC on 5V.
const int MAX_DUTY = 170;
const int STEPS = 100;

// Step 0..STEPS to a duty, through a 2.2 power: the eye answers
// roughly to the logarithm of light, so equal steps of duty do not
// look equal. 2.2 is the usual rule of thumb.
int dutyFor(int step) {
  return lround(pow((float)step / STEPS, 2.2) * MAX_DUTY);
}

void fade(int pin, const char *name) {
  Serial.print(name);
  Serial.println(": up");
  for (int s = 0; s <= STEPS; s++) {
    analogWrite(pin, dutyFor(s));
    delay(20);
  }
  Serial.print(name);
  Serial.println(": down");
  for (int s = STEPS; s >= 0; s--) {
    analogWrite(pin, dutyFor(s));
    delay(20);
  }
}

void setup() {
  // LOW first: nothing on the board holds the transistors off.
  pinMode(WARM_PIN, OUTPUT);
  digitalWrite(WARM_PIN, LOW);
  pinMode(COOL_PIN, OUTPUT);
  digitalWrite(COOL_PIN, LOW);
  Serial.begin(115200);
}

void loop() {
  fade(WARM_PIN, "3000K");
  fade(COOL_PIN, "6500K");
}

"""
  Dual Bright LEDs - a fade that looks even, MicroPython   TK95

  Wiring. Count from the square pad on the TinkerBlock board, parts
  up, header at the bottom:

    GND    -> GND
    VCC    -> 5V (VBUS on a Pico). It only feeds the LEDs.
    3000K  -> GPIO 25 on an ESP32, GPIO 4 on an ESP32-S3, GP14 on a Pico
    6500K  -> GPIO 26 on an ESP32, GPIO 5 on an ESP32-S3, GP15 on a Pico

  Thonny
    Run > Configure interpreter   MicroPython (ESP32) or
                                  MicroPython (Raspberry Pi Pico)
"""

import time
from machine import Pin, PWM

# GPIO numbers. ESP32: 25 and 26. ESP32-S3: 4 and 5. Pico: 14 and 15.
WARM_PIN = 4
COOL_PIN = 5

# Two thirds of full: the cap for VCC on 5V.
MAX_DUTY = 43690
STEPS = 100

# LOW first: nothing on the board holds the transistors off.
Pin(WARM_PIN, Pin.OUT, value=0)
Pin(COOL_PIN, Pin.OUT, value=0)
warm = PWM(Pin(WARM_PIN))
cool = PWM(Pin(COOL_PIN))
for led in (warm, cool):
    led.freq(1000)
    led.duty_u16(0)


def duty_for(step):
    # Through a 2.2 power, so equal steps look equal.
    return round((step / STEPS) ** 2.2 * MAX_DUTY)


def fade(led, name):
    print(name + ": up")
    for s in range(STEPS + 1):
        led.duty_u16(duty_for(s))
        time.sleep_ms(20)
    print(name + ": down")
    for s in range(STEPS, -1, -1):
        led.duty_u16(duty_for(s))
        time.sleep_ms(20)


while True:
    fade(warm, "3000K")
    fade(cool, "6500K")