A low-battery warning

/*
  Voltmeter - low-battery warning                        TK09 / /p/tk09

  Wiring. Count from the square pad on the TinkerBlock board, terminal
  at the top, header at the bottom:

    GND    -> GND
    NC     -> nothing   (both NC pins are unconnected on the board)
    SIG    -> A0 on an Uno, GPIO 34 on an ESP32, GPIO 4 on an
              ESP32-S3, GP26 on a Raspberry Pi Pico

  Terminal: left screw to the battery's minus, right screw to its plus.

  TK01 XL LED, counted from its own square pad:
    GND    -> GND
    SIGNAL -> D9 on an Uno, GPIO 4 on an ESP32, GPIO 5 on an
              ESP32-S3, GP15 on a Pico

  Arduino IDE
    Tools > Board                 your board, e.g. ESP32S3 Dev Module
    Tools > Port                  the one that appears when you plug in
    Tools > USB CDC On Boot       Enabled   (ESP32-S3 only)
    No library needed.
*/

// The pin SIG is wired to. Uno: A0. ESP32: 34. ESP32-S3: 4. Pico: 26.
const int SIG_PIN = A0;
// The pin the TK01 is on. Uno: 9. ESP32: 4. ESP32-S3: 5. Pico: 15.
const int LED_PIN = 9;

// Uno: 5.0 and 1023. Pico: 3.3 and 1023. The ESP32s do not use these.
const float VREF = 5.0;
const float ADC_MAX = 1023.0;

const float SCALE = 5.0;        // the terminal is 5 x SIG
const float CAL = 1.000;        // multimeter / sketch
const int SAMPLES = 16;

const float LOW_V = 7.5;        // warn below this
const float HYSTERESIS = 0.2;   // and stop only above LOW_V + this

bool warning = false;

float sigVolts() {
  float sum = 0;
  for (int i = 0; i < SAMPLES; i++) {
#if defined(ARDUINO_ARCH_ESP32)
    sum += analogReadMilliVolts(SIG_PIN) / 1000.0;
#else
    sum += analogRead(SIG_PIN) * VREF / ADC_MAX;
#endif
  }
  return sum / SAMPLES;
}

void setup() {
  Serial.begin(115200);
  pinMode(LED_PIN, OUTPUT);
}

void loop() {
  float battery = sigVolts() * SCALE * CAL;

  if (!warning && battery < LOW_V) {
    warning = true;
  } else if (warning && battery > LOW_V + HYSTERESIS) {
    warning = false;   // only a real recovery, such as a new battery
  }
  digitalWrite(LED_PIN, warning ? HIGH : LOW);

  Serial.print("battery ");
  Serial.print(battery, 2);
  Serial.println(warning ? " V  LOW" : " V");
  delay(1000);
}

"""
  Voltmeter - low-battery warning, MicroPython         TK09 / /p/tk09

  Wiring. Count from the square pad on the TinkerBlock board, terminal
  at the top, header at the bottom:

    GND    -> GND
    NC     -> nothing   (both NC pins are unconnected on the board)
    SIG    -> GPIO 34 on an ESP32, GPIO 4 on an ESP32-S3,
              GP26 on a Raspberry Pi Pico

  Terminal: left screw to the battery's minus, right screw to its plus.

  TK01 XL LED, counted from its own square pad:
    GND    -> GND
    SIGNAL -> GPIO 4 on an ESP32, GPIO 5 on an ESP32-S3, GP15 on a Pico

  Thonny
    Run > Configure interpreter   MicroPython (ESP32) or
                                  MicroPython (Raspberry Pi Pico)
    Save it to the board as main.py to run it on every power-up.
    Nothing to install: machine, sys and time are built in.
"""

from machine import ADC, Pin
import sys
import time

# The GPIO number SIG is wired to. ESP32: 34. ESP32-S3: 4. Pico: 26.
SIG_PIN = 34
# The pin the TK01 is on. ESP32: 4. ESP32-S3: 5. Pico: 15.
LED_PIN = 4

SCALE = 5.0          # the terminal is 5 x SIG
CAL = 1.000          # multimeter / sketch
SAMPLES = 16
LOW_V = 7.5          # warn below this
HYSTERESIS = 0.2     # and stop only above LOW_V + this

adc = ADC(Pin(SIG_PIN))
led = Pin(LED_PIN, Pin.OUT)

if sys.platform == "rp2":
    def read_once():
        return adc.read_u16() * 3.3 / 65535
else:
    adc.atten(ADC.ATTN_11DB)          # full range; the default is ~1 V
    def read_once():
        return adc.read_uv() / 1_000_000   # calibrated by the firmware

def battery_volts():
    sig = sum(read_once() for _ in range(SAMPLES)) / SAMPLES
    return sig * SCALE * CAL

warning = False
while True:
    battery = battery_volts()
    if not warning and battery < LOW_V:
        warning = True
    elif warning and battery > LOW_V + HYSTERESIS:
        warning = False       # only a real recovery, a new battery
    led.value(1 if warning else 0)
    print("battery {:.2f} V{}".format(battery, "  LOW" if warning else ""))
    time.sleep_ms(1000)