EEPROM Memory

What it is

A memory chip on two wires. Write a byte, pull the power, come back a year later, and the byte is still there. The chip is an AT24C128: 16,384 bytes, each rewritable about a million times and kept for 40 years with no power.

It talks I2C at address 0x50, which is fixed: the chip's address pins are wired to GND on the board. Two pull-up resistors on SDA and SCL end at VCC, by way of a jumper on the back marked I2C PULL-UP. There is no LED; a scan that finds 0x50 is the sign it is alive.

The page this replaces said the address could be moved to 0x51 to 0x57. On this board it cannot. It also left out the rule that decides the wiring: VCC sets the voltage on SDA and SCL, so VCC goes to your board's logic supply.

Wiring, in four lines

1. GND to your board's GND.
2. VCC to your board's logic supply. Never 5V beside a 3.3 V board.
3. SDA to your board's SDA pin.
4. SCL to your board's SCL pin.

Parts up, header at the bottom, the pins read GND, VCC, SDA, SCL from left to right, and GND is the square pad. The back prints TK31 EEPROM MEMORY and NON-VOLATILE MEMORY but no pin names; turned over, the square pad is on the right.

Four rules

Example

#include <Wire.h>

const int EEPROM_ADDR = 0x50;   // fixed on the TK31

void writeByte(uint16_t at, uint8_t value) {
  Wire.beginTransmission(EEPROM_ADDR);
  Wire.write((uint8_t)(at >> 8));     // address, high byte
  Wire.write((uint8_t)(at & 0xFF));   // then low byte
  Wire.write(value);
  Wire.endTransmission();
  delay(5);                           // the chip is writing
}

int readByte(uint16_t at) {
  Wire.beginTransmission(EEPROM_ADDR);
  Wire.write((uint8_t)(at >> 8));
  Wire.write((uint8_t)(at & 0xFF));
  Wire.endTransmission(false);
  Wire.requestFrom(EEPROM_ADDR, 1);
  return Wire.available() ? Wire.read() : -1;
}

void setup() {
  Serial.begin(115200);
  Wire.begin();                       // the board's default I2C pins
  writeByte(0, 123);
  Serial.println(readByte(0));        // 123, before and after power-off
}

void loop() {
}

import time
from machine import I2C, Pin

# SDA, SCL. ESP32: 21, 22. ESP32-S3: 8, 9. Pico: 4, 5.
i2c = I2C(0, sda=Pin(21), scl=Pin(22), freq=100_000)
EEPROM = 0x50                        # fixed on the TK31

i2c.writeto_mem(EEPROM, 0, bytes([123]), addrsize=16)
time.sleep_ms(5)                     # the chip is writing
print(i2c.readfrom_mem(EEPROM, 0, 1, addrsize=16)[0])

Where to start

The handbook below is ten short articles, each with a working figure. The first byte is the whole build in four wires, and VCC sets the bus is the one page that explains the wiring.

For more than one byte at a time, read five milliseconds a write and sixty-four-byte pages. Before you save anything in a loop, a million writes. If the chip will not answer, when it does not answer.